1 GnuPlot |
Beispiel-Messdaten |
Daten in separater Datei |
Daten in Gnuplot-Eingabe |
Linienzug |
Geglättete Linie |
Berechnungen aus den Messwerten |
Bei der Aufnahme einer Strom-Spannungs-Kennlinie wurden Werte entsprechend der nachfolgenden Tabelle ermittelt:
Spannung in V | Strom in mA |
---|---|
1.08 | 0.227 |
2.12 | 0.455 |
3.12 | 0.664 |
4.13 | 0.907 |
5.19 | 1.121 |
6.52 | 1.337 |
7.27 | 1.544 |
8.09 | 1.857 |
9.78 | 2.104 |
10.86 | 2.229 |
Die Daten werden in eine Text-Datei geschrieben. Jede Zeile enthält einen x-Wert und den zugehörigen y-Wert, durch ein oder mehrere Leerzeichen oder Tabulatoren getrennt.
1.08 0.000227
2.12 0.000455
3.12 0.000664
4.13 0.000907
5.19 0.001121
6.52 0.001337
7.27 0.001544
8.09 0.001857
9.78 0.002104
10.86 0.002229
Mit der Datei gp0016.gp wird geplottet:
set xrange [0.0:11.0]
set yrange [0.0:0.0024]
set xlabel "Spannung"
set ylabel "Strom"
set key left top
plot 'gp2d0012.dat' title "Kennlinie"
Die Daten können auch mit in die Gnuplot-Eingabe geschrieben
werden. Als Dateiname wird dann der Bindestrich verwendet (wie ein
normaler Dateiname auch von einfachen Anführungszeichen
umgeben).
Ein einzeln stehendes "e" markiert das Ende der Datensätze.
set xrange [0.0:11.0]
set yrange [0.0:0.0024]
set xlabel "Spannung"
set ylabel "Strom"
set key left top
plot '-' title "Kennlinie"
1.08 0.000227
2.12 0.000455
3.12 0.000664
4.13 0.000907
5.19 0.001121
6.52 0.001337
7.27 0.001544
8.09 0.001857
9.78 0.002104
10.86 0.002229
e
Sollen die Punkte als Linienzug dargestellt werden, wird zur plot-Anweisung die Option
with lines
angegeben.
set xrange [0.0:11.0]
set yrange [0.0:0.0024]
set xlabel "Spannung"
set ylabel "Strom"
set key left top
plot 'gp2d0012.dat' title "Kennlinie" with lines
Um die Linie zu glätten, wird die zusätzliche Option
smooth Methode
mit angegeben.
set xrange [0.0:11.0]
set yrange [0.0:0.0024]
set xlabel "Spannung"
set ylabel "Strom"
set key left top
plot 'gp2d0012.dat' title "Kennlinie" with lines smooth bezier
Das nachfolgende Bild zeigt eine Übersicht gebräuchlicher Glättungsmethoden.
set xrange [0.0:12.0]
set yrange [-0.5:1.5]
plot 'gpsmooth.dat' title "Punkte", \
'gpsmooth.dat' title "bezier" with lines smooth bezier, \
'gpsmooth.dat' title "sbezier" with lines smooth sbezier, \
'gpsmooth.dat' title "csplines" with lines smooth csplines, \
'gpsmooth.dat' using 1:2:(1.0) title "acsplines" with lines \
smooth acsplines
Mit
help smooth
erhalten Sie weiterführende Informationen, insbesondere auch zu den verschiedenen Glättungsmethoden.
Wird dem plot-Befehl die Option
using Format
übergeben, kann sowohl der x- als auch der y-Wert jedes Punktes durch Berechnung aus den Daten gewonnen werden.
Das Format besteht aus x-Auswahl und y-Auswahl, getrennt durch einen Doppelpunkt.
Sowohl x- als auch y-Auswahl können auf zwei Wegen angegeben werden:
set xrange [0.0:11.0]
set xlabel "Spannung"
set ylabel "Widerstand"
set key left top
plot 'gp2d0012.dat' using 1:($1/$2) notitle with lines smooth bezier
Mit
help using
erhalten Sie weiterführende Informationen.