Faltung

© C. Roppel, Fachhochschule Schmalkalden, Fachbereich Elektrotechnik

Beschreibung

Das Ausgangssignal y(t) eines LTI-Systems mit der Impulsantwort h(t) erhält man durch Faltung des Eingangssignals x(t) mit der Impulsantwort. Die Faltung ist definiert als y(t) = x(t) ⋆ h(t) = (∫_(-∞)^∞)x(τ)h(t-τ)dτ. In diesem Beispiel ist das Eingangssignal x(t) ein Rechteckimpuls der Breite (Subscript[T, 0]) und das LTI-System ist ein RC-Tiefpass mit der Impulsantwort 
h(t) = (1/RC)exp(-t/RC). 
 
Im oberen Bild sieht man die Funktionen x(τ) (rot) und h(t - τ) (blau).   Die Fläche unter dem Produkt der beiden Funktionen ist grau schraffiert. Diese Fläche ist gleich dem Wert des Integrals und damit gleich dem Ausgangssignal zum Zeitpunkt t. Dieser Wert ist im unteren Bild als blauer Punkt markiert.
 
Vgl. auch Beispiel 2-2 in [Roppel, C.: Grundlagen der digitalen Kommunikationstechnik, Hanser Verlag, 2006].

(* Eingangssignal *)
rect[x_] := 1 /; x <= 0.5 && x >= -0.5
rect[x_] := 0 /; x >0.5 || x < -0.5

(* Impulsantwort *)
rc = 0.5;
h[x_] := (1/rc) Exp[-x/rc] /; x >= 0
h[x_] := 0 /; x < 0

(* Ausgangssignal *)
y[x_, t0_] :=  1 - Exp[-x/rc] /; x >= 0 && x≤t0
y[x_, t0_] :=  (Exp[t0/rc] - 1)Exp[-x/rc] /; x>t0
y[x_, t0_] := 0 /; x < 0

Manipulate[
GraphicsColumn[{
Show[ Plot[h[t -tau], {tau, -1, 5}, PlotStyle->{{Thickness[0.008]}}, PlotRange->{-0.1, 2.1}, AxesLabel->{"τ"}, PerformanceGoal->"Quality"], 
Plot[rect[tau/pw- 1/2], {tau, -1, 5}, PlotStyle->{{Thickness[0.008], RGBColor[1, 0, 0]}}] ,
Plot[h[t -tau] rect[tau/pw - 1/2], {tau, -1, 5}, PlotRange->{-0.1, 2.1}, Filling->Axis, PerformanceGoal->"Quality"]],
Show[Plot[y[x, pw], {x, -1, 5}, PlotRange->{-0.1, 1.1}, AxesLabel->{"t", "y(t)"}], Graphics[{PointSize[Large],Blue, Point[{t, y[t, pw]}]}]]},
ImageSize->{400,450}],
Style["Zeit",Bold],
{t, -1, 5, 0.01,Appearance->"Labeled"}, 
Delimiter, 
Style["Pulsbreite",Bold],
{{pw, 1, "(Subscript[T, 0])"}, 0.5, 3, 0.1,Appearance->"Labeled"}, 
ControlPlacement->Left, SaveDefinitions->True]